İki və daha çox sütuna əsasən məlumatın gətiriliməsi haqqında ilk həll yolunu əvvəlki məqaləmizdə yazmışdıq. İndi isə eyni nəticəni başqa funksiyalar ilə əldə etməyə çalışacayıq. Bu həll yolunda biz yenə köməkçi sütundan istifadə edəcəyik. Asanlıq olması məqsədi ilə, əvvəlki nümunə faylından istifadə edəcəm.

Ikinci həll yolu olaraq INDEX-SUMIFS kombinasiyasından istifadə edəcəyik. Funksiyaların istifadəsi axtarılan dəyərin rəqəm və ya mətn olmasına görə dəyişir. Hər birisinə ayrı ayrılıqda baxaq

Axtarılan dəyər rəqəm isə

Axtarılan dəyərin rəqəm olması halında həll yolumuz asan olacaq. Burda SUMIFS funksiyasını VLOOKUP əvəzi istifadə olunacaq. Misal üçün, Regionun “Bakı-Abşeron”, Satış Nöqtəsinin isə “Sahib Topdan” olması halında biz sadə SUMIFS funksiyası istifadə edəcəyik

=SUMIFS(D:D;B:B;"Bakı-Abşeron";C:C;"Sahib Topdan")   Nəticə: 3545

Ancaq, əgər cədvəlimizdə dublikat məlumatların olma ehtimalı varsa o zaman qeyd olunan funksiya həmin kriteriyaları toplayacaq. Biz əgər VLOOKUP funksiyasındakı kimi ilk gördüyü məlumatı əldə etmək istiyiriksə o zaman köməkçi süttundan istifadə edəcəyik. Köməkçi sütunda (“Say”) aşağıdakı funksiyanı “E2” xanasına daxil edib aşağı çəkirik

=COUNTIFS($B$2:B2;B2;$C$2:C2;C2)

Bu funksiya, hər bir sətrdə, daxil olunduğu sətrə qədər kriteriyaların sayını verəcək. Misal üçün, “Şimal Zonası – Qafqaz Topdan” (qırımızı ilə göstərilib) cədvəlimizdə iki dəfə təkrarlanır. Funksiyanın köməkliyi ilə, ilk rastladığı sətrdə “1”, digərində isə “2” rəqəmini verdi. İndi isə bunu SUMIFS funskiyasında göstərəciyik.

=SUMIFS(D:D;B:B;"Şimal Zonası";C:C;"Qafqaz Topdan";E:E;1)             Nəticə: 6962

Burda biz, üçüncü kriteriya əlavə edərək qarşısında yalnız “1” rəqəmi olanları toplatdıq.

Axtarılan dəyər rəqəm və ya mətn isə

İndiki həll yolunda isə, axtarılan dəyərin rəqəm və ya mətn olmasının fərqi yoxdur, hər iki məlumat növü üçün keçərlidir.

Burda, axtarılan məlumatın mətn olması səbəbi ilə (Əməkdaş) biz SUMIFS funksiyasına axtarılan dəyəri tətbiq edə bilmirik. Bu səbəbdən, köməkçi sütun (A sütunu) yaratdıq və ilk sətrdən etibarən, 1-dən başlamaq şərti ilə sıra sayı verdik. Əsas məqsədimiz odur ki, axtarılan dəyərin neçənci sətrdə olduğunu tapaq.

Regionun “Aran Zonası”, Satış nöqtəsinin isə “Nuru Topdan” olması halında funksiyamızın ilk hissəsi bu şəkildə olacaq

=SUMIFS(A:A;B:B;"Aran Zonası";C:C;"Nuru Topdan")              Nəticə:9

Funksiyada, toplama diapazonu kimi, sıra sayları olan köməkçi sütunu seçdik. Bu şəkildə biz, “Aran Zonası – Nuru Topdan” şərtlərinin neçənci sətrdə olmasını tapdıq. İndi isə, INDEX funksiyası ilə əldə etdiyimiz rəqəmdən istifadə edərək 9-cu sətrdəki “Əməkdaş” adını gətirəcəyik

=INDEX(D:D;SUMIFS(A:A;B:B;"Aran Zonası";C:C;"Nuru Topdan"))   Nəticə: Əhmədov Zaur

Cədvəlimizdə əgər dublikat sətrlər varsa (Qafqaz Topdan kimi) o zaman COUNTIFS funksiyasını daxil etdiyimiz əlavə köməkçi sütundan istifadə edəcəyik.

=INDEX(D:D;SUMIFS(A:A;B:B;"Şimal Zonası";C:C;"Qafqaz Topdan";E:E;1))   Nəticə: Dadaşov Oqtay

Bir digər nüans da odur ki, əgər məlumat tapılmazsa, yəni SUMIFS funksiyasının nəticəsi “0” olarsa, o zaman INDEX funksiyası səhf nəticə gətirə bilər. Bunu sadə IF funksiyası ilə düzəliş etmək mümkündür.

=IF(SUMIFS(A:A;B:B;"Şimal Zonası";C:C;"Qafqaz Topdan";E:E;1)=0;"";INDEX(D:D;SUMIFS(A:A;B:B;"Şimal Zonası";C:C;"Qafqaz Topdan";E:E;1)))

Bu metodun müsbət və mənfi cəhətləri

Əgər əlinizdə olan cədvəllərdə dublikatlar yoxdursa və ya həmin məlumatlardan əmin isəniz bu metodu rahatlıqla istifadə edə bilərsiniz. Ancaq, məlumatın güvənirliyi cəhətdən VLOOKUP, INDEX-MATCH metodu daha uyğundur. Bu mövzu haqqında daha 1-2 əlavə metodlar da var ki, onları da iləriki tarixlərdə paylaşacam.

Məqalənin videolu izahını Youtube kanalından izləyə bilərsiniz