Müxtəlif növ Məlumatların Sayımı – COUNT, COUNTA, COUNTBLANK, SUMPRODUCT

Başlanğıc

Exceldə sayım funksiyaları dedikdə COUNT ilə başlayan funksiyalar nəzərdə tutulur. Bugünkü məqalədə, COUNTIF(S)-dən başqa digər sayım funksiyaları haqqında məlumat verəcəyik. Bunlar, COUNT, COUNTA və COUNTBLANK funksiyalarıdır. Eyni zamanda, SUMPRODUCT ilə sayım funksiyalarının hesablaya bilmədikləri məlumat növlərini hesablayacayıq.

Aşağıdakı cədvəldə, məlumat növlərinə görə funksiyaların davranışları göstərilib. Məlumatların qarşısında onların təsviri verilib. Hər bir funksiyanın nəzərə aldığı məlumat növü “1” rəqəmi ilə göstərilib.

Rəqəm məlumatlarının sayımı

COUNT funksiyası verilən diapazonda (siyahıda) neçə ədəd rəqəm olduğunu hesablayır. Şəkildə, 1-6-8 ci məluamatlar rəqəm kimi tanınıb. Tarix məlumatları da rəqəm olduqları üçün COUNT funksiyası həmin məlumatı nəzərə alıb. Ancaq, 5-ci sətrdə rəqəm mətn formatında olduğu üçün funksiya onu nəzərə almayıb.

=COUNT(B2:B9)             "Nəticə: 3"

Eyni nəticəni SUMPRUDUCT ilə də əldə edə bilərik. Funksiya daxilində, rəqəmlərin tanıdılması üçün ISNUMBER funskiyasından istifadə ediləcək.

=SUMPRODUCT(--ISNUMBER(B2:B9))        "Nəticə: 3"
Boş olmayan xanaların sayımı

COUNTA funksiyası verilən diapazonda (siyahıda) neçə ədəd boş olmayan xana olduğunu hesablayır. Göstərilən nümunədə (şəkil) də, funksiya təkcə boş xananı nəzərə almayıb. =”” funksiyası daxil edilən xananın da daxilində məlumat olduğunu nəzərə alıb. Funksiya üçün məlumat növünün fərqi yoxdur, əgər xana boş deyilsə həmin xanaları nəzərə alacaq.

=COUNTA(B2:B9)                  "Nəticə: 7"

COUNTA funksiyası ilə ISBLANK funksiyası oxşardır, amma tərs yönüylə. Yəni, ISBLANK funksiyasının boş xana kimi nəzərə almadığı məlumatları COUNTA nəzərə alır. Bu səbəbdən ISBLANK funksiyasını NOT funksiyası ilə bərabər istifadə edəcəyik.

=SUMPRODUCT(--NOT(ISBLANK(B2:B9)))       "Nəticə :7"

Qeyd:

Göstərilən qısa videoda, xanalara =”” funksiyası daxil edilir və daha sonra həmin funksiya dəyər kimi yapışdırılaraq funksiyadan çıxarılır. Xananın daxilində heçbir məlumat olmamasına baxmayaraq COUNTA (NOT-ISBLANK) funksiyası həmin xananın boş olmadığını göstərir. Ancaq, xanaya iki dəfə kliklədikdən (və ya F2, xananın silinməsi) sonra xananın boş olduğunu göstərir.

Bu kimi hallara, ERP sistemindən alınmış formatlı excel fayllarında rast gəlmək olar. Yəni, xana boşdur ancaq funksiyalar həmin xananı dolu kimi hesablayır. Bu kimi hallarda, LEN funksiyasından istifadə edərək problemi həll edə bilərsiniz. Misal üçün

"Bu iki funksiya xananın boş olmadığını göstərir"
=IF(COUNTA(E2)>0;"Doludur";"Bosdur")
=IF(NOT(ISBLANK(E2));"Doludur";"Bosdur")

"Alternativ həll yolu"
=IF(LEN(E2)>0;"Doludur";"Bosdur")
Boş xanaların sayımı

COUNTBLANK funksiyası, verilən diapazonda (siyahıda) neçə ədəd boş xana olduğunu hesablayır. Üstdəki nümunədə, funksiya həm boş xananı, həm də uzunluğu sıfır olan (=””) xananı boş kimi nəzərə alır.

=COUNTBLANK(B2:B9)       "Nəticə:2"

Qeyd: Üstdəki nümunədə bizim 8 ədəd məlumatımız var. Məntiqən fikirləşə bilərik ki, xanalar ya boş ya da dolu ola bilər və ikisnin toplamı seçilən diapazonun toplam xana sayısını verməlidir. Ancaq, boş olan xanaların sayı ilə boş olmayan xanaların sayı toplandığında 9 rəqəmini alırıq. Bunun səbəbi, “uzunluğu 0 olan məlumatları” COUNTA və COUNTBLANK funksiyaların hər ikisi də nəzərə almasıdır.

Uzunluğu sıfır olan xanaların sayımı

Həmin xanaları LEN funskiyası ilə təyin etmək mümkündür. Ancaq, diapazonda əgər xəta məlumatı varsa LEN funksiyası hesablama aparmayacaq.

=SUMPRODUCT(--(LEN(B2:B9)=0))
Xata məlumatlarının sayımı

COUNT funksiyaları xəta məlumatlarını ayrıca tanımadığı üçün ISERROR funksiyasından istifadə edəcəyik.

=SUMPRODUCT(--ISERROR(B2:B9))
Mətn formatında olan rəqəmlərin sayımı

Bu kimi məlumatların iki xüsusiyyəti var: üzərində riyazı əməliyyat onları rəqəmə çevirir və mətndirlər. Bu iki xüsusiyyət funksiya daxilində göstərəcəyik

=SUMPRODUCT(ISNUMBER(--B2:B9)*ISTEXT(B2:B9))

Əvvəlcə “–” işarəsi ilə xanalar üzərində riyazi əməliyyat aparıldı. Burda mətn formatında olan rəqəm, rəqəm formatına çevrildi. Daha sonra, ISNMUBER ilə həmin məlumatların rəqəm olması yoxlanıldı. Sonda isə, ISTEXT ilə əldə olunan TRUE-FALSE siyahısı ISNUMBER siyahısı ilə vurma əməliyyatı aparıldı. Əgər xana mətn formatında rəqəmdirsə, hər iki siyahıda TRUE nəticəsi alacaq.

Formula olan xanaların sayımı

Məlumat funksiyalarından ISFORMULA bizə xanada daxil edilən məlumatın funksiya olmasını bildirir. Verilən diapazonda funksiya daxil edilən xanaların sayını əldə etmək üçün

=SUMPRODUCT(--ISFORMULA(B2:B9))

Digər məlumat növlərinin sayımı üçün, IS ilə başlayan (ISTEXT, ISREF və s.) məlumat funksiyalarını eyni metodla istifadə etmək mümkündür.

Məqalədə istifadə olunan funksiyalar haqqında oxumaq üçün

Exceldə Ən Güclü Funksiyalardan biri – SUMPRODUCT

Məlumat Funksiyaları (ISNUMBER, ISEVEN, ISODD, ISTEXT …)

Nümunə faylını yükləmək üçün

Başlanğıc
Daha rahat avtomatlaşdırma üçün Exceldə bazaları necə qurmalı?

Bir çoxumuz Exceli işlərimizi avtomatlışdırmaq üçün istifadə edirik. İstəyirik ki, bir dəfə cədvəlimizi və funksiyalarımızı quraq və daha sonra eyni əziyyəti çəkmiyək. Bu şəkildə, həmin Excel faylında həm hesabatlarımız, həm də arxivlədiyimiz məlumatlar olsun və istənilən vaxt həmin bazadan istifadə edək. Ancaq, bunu etməyə çalışarkən cədvəllərimiz üçün düzgün struktur yaratmır və …

Başlanğıc
“Cədvəl”lərdə (Table) Funksiya İstifadəsi

Cədvəllərdə funksiyanın istifadəsi iki şəkildə ələ alınacaq: cədvəl içində funksiya istifadəsi və kənardan yazılan funksiyalarda cədvələ referans verilməsi. Amma funksiya istifadəsinə keçməmişdən qabaq cədvəlin hissələri (elementləri) haqqında qısa məlumat vermək düzgün olardı. Cədvəlimizi yaradan kimi “Table Tools” adında yeni menümüz yaranır. Excel avtomatik olaraq cədvəllərimizə “Table1,2…..” şəklində adlar təyin edir. …

Başlanğıc
Exceldə Cədvəl (Table) İstifadəsinin Üstünlükləri

Excelin 2007 versiyasından sonra “Cədvəl” (Table) xüsusiyyətini təqdim etdi. “Cədvəl”-lərin köməkliyi ilə məlumatlarımız strukturlaşdırılır, qruplaşdırılır və onları analız etmək daha asan olur. İstifadəsi və yaradılması çox asan olmaqla bərabər, əməliyyatlarda çox üstünlüklər verir. Bəzi üstünlükləri: Yeni məlumatlar daxil edildikçə “Cədvəl” genişliyir və yaradılan funksiya, pivot və qrafiklərdə diapazonları yeniləməyə ehtiyac qalmır. Funksiya …